|
|
|
|
|||||
|
||||||
From: (no name) (no email)
Date: Sun Mar 09 2008 - 15:04:32 EDT
Here is a program, written in elementary BASIC, for calculating the proper
propeller for displacement boats. I posted it to the TWL a few years ago but I
keep getting requests for it from time to time. It will get you in the
ballpark
and should provide a good starting point for selecting the right propeller
after repowering. In addition to specifying propeller characteristics, the
program performs a horsepower calculation necessary to achieve hull speed and
indicates the efficiency of various propeller pitches, diameters, and rpms.
This
program works better than the one used by Michigan Wheel or Federal Propeller.
It will run on ANY computer which supports a Basic interpreter. Try it and
see.
BASIC PROPELLER CALCULATION FOR DISPLACEMENT HULLS - L. R. Zeitlin
This program is designed to give a quick estimate of propeller
specifications for typical displacement hulls such as sailboats and trawlers.
I must
caution that propeller specification is an arcane art full of compromises and
approximations. It is rare good fortune if you get it right the first time.
This
program will get you in the ballpark, about + or - 5% of the right value.
>From there on it is experimental trial and error. From a theoretical point of
view pure displacement hulls work best with large, slow turning props.
Generally
the diameter is determined by hull clearances. The pitch is the main variable
under your control. Fortunately the pitch of most bronze propellers can be
adjusted a couple of inches either way at relatively low cost. While the
program
is designed to give you the most efficient prop for a given engine speed,
reduction ratio and hull speed, most of us can live with, and even enjoy boats
that donbt squeeze the last mile from a tank of fuel.
The logic of the program is simple. After entering hull and engine
characteristics, hull speed is calculated using the standard formula KT = 1.34
x b
WL. An estimate of power required to reach hull speed is obtained using
Keithbs
formula (line 90). This usually works out to about 1 HP per 500 lb
displacement. A slip estimate is made using Gerrbs formula for displacement
hulls (line
110). Given power, slip and shaft RPM, propeller pitch and diameter are
calculated using Crouchbs method.
The more complex Bp (power coefficient) method of propeller
specification is used as a check on the simpler approach. Va (velocity of
advance) is
estimated (lines 347, 348) and Bp is calculated (line 350). Lines 350 through
410
provide estimates of Delta (advance coefficient), P/D (pitch/diameter) ratio
and efficiency based on the Taylor Bp charts. The calculation is made to
provide optimum efficiency at a given Bp. It is not necessary to know exactly
what
these terms mean. Elaborate tables have been plotted delineating the
relationship between power coefficient, advance coefficient and efficiency.
The program
uses the variables which you input to specify the propeller which will bring
you closest to the point of maximum efficiency.
For both types of calculation, engine power is derated 5% to account for
gearbox and shaft losses. Small modifications in propeller specification (up
to 15%) are usually acceptable if pitch is increased 2b for every 1b
decrease
in diameter. Since the equation constants are based on actual in water and
tank tests, any inputs which would give a result out of the measured range is
rejected. For example, if you specify a 6" diameter propeller to push a 40'
trawler, you will be asked to try again.
Of course you may not want the most efficient propeller for a sailboat
or motorsailer. Efficient propellers tend to be big and have a lot of blade
area. This translates into unacceptable drag when sailing. In that case, play
around with the prop RPM and the diameter until you find one that suits.
This is a bare bones program written in elementary Basic. It should run
on any computer which supports a Basic interpreter, even palmtops. All PCs can
run it from the TRS 80 or Commodore Pet to the latest Dell or iMac. If your
computer does not have a simple Basic interpreter, you can download several
freeware versions from the internet. Try (www.chipbasic.com/). I use the
program
on an old HP100 LX palmtop running a copy of Radio Shack Basic for the PC. No
provision is made for printing. I assume that you have a pencil and pad handy
to record the results. If you have a Basic interpreter, simply copy the text
file starting at line 10. Most Basic programs are able to interpret text
files.
If you have comments or questions, contact me at:
10 PRINT "Propeller calculation program"
20 PRINT "Copyright 1997: L. Zeitlin"
27 FOR x = 1 TO 30000!: NEXT x
29 PRINT: PRINT "CROUCH'S METHOD FOR OPTIMUM HULL SPEED PROPELLER
CALCULATION."
30 INPUT "Waterline length in ft."; L
40 INPUT "Displacement in lbs.";D
50 INPUT "Engine rated HP"; HP
52 HP=HP*.95 'assume 5% HP loss in power line.
55 INPUT "Engine RPM at rated HP"; RPM
57 INPUT "Percent RPM used for calculations";PRPM
58 DRPM=PRPM*RPM/100 'desired RPM
59 HPREV=HP/RPM 'horsepower per revolution.
60 INPUT "Gearbox reduction ratio"; RG
70 HS= L^.5 * 1.34 'hull speed calculation.
80 PRINT "Hull speed ="; INT(HS *100)/100;"KT"
90 RHP = D * ((HS/(11.963 * L^.5))^3) ' Keith's formula, required HP for hull
speed.
100 PRINT "Required HP ="; INT(RHP *100)/100
105 IF RHP > HPREV*DRPM THEN GOTO 900
110 SLIP = 1.4/(HS^.57) 'estimate of slip, Gerr's formula
120 HSRPM = DRPM/RG 'desired shaft RPM at hull speed.
130 PITCH = (HS*1215.6/(1-SLIP))/HSRPM
140 DIAMETER = (632.7 * ((HPREV*DRPM)^.2))/HSRPM^.6
150 PRINT:PRINT "Three bladed propeller:"
160 PRINT "Diameter ="; INT(DIAMETER * 10)/10; "inches."
170 PRINT "Pitch =" INT(PITCH * 10)/10; "inches."
180 PRINT:PRINT "Two bladed propeller:"
190 PRINT "Diameter ="; INT(DIAMETER * 10.5)/10; "inches."
200 PRINT "Pitch =" INT(PITCH * 10.1)/10; "inches."
205 PRINT "Slip estimate=";INT(SLIP*100)/100;"percent.
210 Thrust = 62.72 *((HP*PRPM/100*DIAMETER/12)^.67)
220 PRINT: PRINT "Static thrust =";INT(Thrust * 10)/10;"pounds."
225 PRINT:INPUT "Would you like to try another calculation using Crouch's
method (Yes=1, No=2)";Q
226 CLS
227 IF Q=1 THEN GOTO 30
230 PRINT:INPUT "Would you like to try the Bp method of optimum propeller
calculation (Yes=1, No=2)"; Q
240 IF Q=2 THEN GOTO 500
250 CLS
260 PRINT "Bp METHOD OF OPTIMUM PROPELLER CALCULATION."
263 INPUT "Choose method: (1) Calculate block coefficient. (2) Use
average block coefficient."; Q
264 IF Q=2 THEN GOTO 300
270 INPUT "Waterline beam in ft. =";WLB
280 INPUT "Hull draft, excluding keel or skeg, in ft. ="; DFT
290 Cb = D/(L*WLB*DFT*64)
295 PRINT "Block coefficient ="; INT(Cb * 100)/100
296 GOTO 303
300 Cb = .53
303 INPUT "Desired engine RPM"; DRPM: DHP = DRPM * HPREV
306 PRINT "Available shaft HP at desired RPM ="; INT(DHP *10)/10
310 INPUT "Desired speed in Kt."; HS
313 RHP = D * ((HS/(11.916 * L^.5))^3) 'required HP for desired speed.
316 IF RHP > HPREV*DRPM THEN GOTO 1000
318 PRINT "Required HP for desired speed ="; INT(RHP *10)/10
320 SRPM = DRPM /RG 'shaft RPM.
330 SHP = DHP 'available HP at desired RPM
335 DX=0
347 Wf = 1.11 -(.6*Cb)
348 Va = HS * Wf
349 PRINT "Va="; INT(Va*100)/100
350 BP = (SRPM * SHP^.5)/Va^2.5
355 PRINT "BP"; INT(BP *10)/10
360 DELTA = 103.143 + (4.73 * BP) -(.034 * BP^2) + ((1.57/10000) * BP^3) -
((2.964/10^7)* BP^4)
361 IF DELTA <0 THEN PRINT "Entered values out of range. Try again."
362 IF DELTA <0 GOTO GOTO 303
365 DIAFT = (Va*DELTA)/SRPM
367 PRATIO = 1.014 - (.014 * BP) + ((1.72/10000) * BP^2) - ((9.873/10^7) *
BP^3) + ((2.047/10^9) * BP^4)
370 PRINT "DELTA"; INT(DELTA *10)/10
375 PRINT "DIAFT"; INT(DIAFT *100)/100
380 DIAIN = DIAFT * 12
395 PRINT"P/D RATIO"; INT(PRATIO *100)/100
397 PITCH = PRATIO*DIAFT
398 SLIP = 1-(HS*101.3/(PITCH*SRPM))
399 If SLIP <0 THEN PRINT "Entered values out of range. Try again."
400 IF SLIP <0 GOTO 303
410 EFF = .742 - (.006 * BP) + ((5.086/10^5) * BP^2) - ((2.209/10^7) * BP^3)
+ ((3.835/10^10) * BP^4)
420 PRINT "Three blade prop diameter ="; INT(DIAIN *100)/100;"inches."
425 PRINT "Two blade prop diameter =" INT(DIAIN * 105)/100;"inches."
430 PRINT "Pitch ="; INT(PRATIO * DIAIN*100)/100;"inches."
440 PRINT "Slip ="; INT(SLIP*100)/100;"percent."
450 PRINT "Efficiency ="; INT((EFF-(DX/2))*100)/100; "percent."
451 Thrust = 62.72 *((RHP*DIAFT)^.67)
452 PRINT "Static thrust =";INT(Thrust * 10)/10;"pounds."
455 PRINT: INPUT "Do you wish to modify engine and speed variables (Yes=1,
No=2)";Q
456 IF Q=1 THEN GOTO 303
457 INPUT "Do you wish to change recommended propeller diameter (Yes=1,
No=2)";Q
458 IF Q=1 THEN GOSUB 2000
460 PRINT:INPUT "Another propeller calculation? (Yes=1, No=2)"; Q
465 IF Q=1 THEN CLS: GOTO 29
470 'IF Q=1 THEN GOTO 30
500 PRINT "GOODBYE"
505 FOR x = 1 TO 10000: NEXT x
510 END
900 PRINT "The engine does not have enough power to reach indicated speed."
902 INPUT "Do you wish to modify initial variables (Yes=1, N=2)";Q
903 IF Q=1 THEN GOTO 30
904 IF Q=2 THEN GOTO 500
905 RETURN
1000 PRINT "The engine does not have enough power to reach indicated speed."
1002 INPUT "Do you wish to modify initial variables (Yes=1, N=2)";Q
1003 IF Q=1 THEN GOTO 303
1004 IF Q=2 THEN GOTO 500
1005 RETURN
2000 INPUT "Desired diameter in inches"; DDIAIN
2005 DX = 1-(DDIAIN/DIAIN)
2010 DIAFT =DDIAIN/12
2020 DELTA = (SRPM * DIAFT)/Va
2025 PRATIO = (3.28)
-(.03*DELTA)+((1.231/10000)*DELTA^2)-((1.719/10000000#)*DELTA^3)
2027
2030 GOTO 370
2040 RETURN
**************
It's Tax Time! Get tips, forms, and advice on AOL Money &
Finance.
(http://money.aol.com/tax?NCID=aolprf00030000000001)
_______________________________________________
http://lists.samurai.com/mailman/listinfo/trawlers-and-trawlering
To unsubscribe or modify your subscription options (get password, change email address, etc) go to: http://lists.samurai.com/mailman/options/trawlers-and-trawlering
Trawlers & Trawlering and T&T are trademarks of Water World
Productions. Unauthorized use is prohibited.
|